Bidimensionales

Un arreglo unidimensional, tambien conocido como matriz, es una estructura que organiza los datos en filas y columnas, similar a una tabla o una hoja de cálculo (como Excel).

Cada dato dentro de la matriz se identifica mediante dos índices:

• Uno para la fila.
• Otro para la columna.

Características principales:

• Tiene dos dimensiones: filas y columnas.
• Se necesita un par de índices para acceder a cada elemento.
• Permite representar datos de manera tabular.

Declaración de una matriz:

  Definir notas Como Real;
  Dimension notas[3, 4];

Esto crea una tabla de 3 filas y 4 columnas.

Acceder a un elemento:

  notas[0,2] <- 8.5;  // Asigna 8.5 a la primera fila, tercera columna

Recorrer una matriz:

Normalmente usamos dos bucles anidados: uno para filas y otro para columnas.

  Para fila <- 0 Hasta 2 Hacer
       Para columna <- 0 Hasta 3 Hacer
            notas[fila, columna] <- 0;
       FinPara
  FinPara

Ejemplo práctico:

Crear una tabla para almacenar números del 1 al 5, sus cuadrados y cubos:

  Proceso NumerosCuadradosCubos
      Definir tabla Como Entero;
      Definir fila, columna Como Entero;
      Dimension tabla[5,3];
							
      Para fila <- 0 Hasta 4 Hacer
           tabla[fila,0] <- fila + 1;
           tabla[fila,1] <- (fila + 1)^2;
           tabla[fila,2] <- (fila + 1)^3;
      FinPara
						
      Escribir "Número  Cuadrado  Cubo";
      Para fila <- 0 Hasta 4 Hacer
           Para columna <- 0 Hasta 2 Hacer
                Escribir Sin Saltar tabla[fila,columna], " ";
           FinPara
           Escribir "";
      FinPara
  FinProceso