Condicionales

¿Qué son las Estructuras Condicionales?

Las estructuras condicionales permiten que un programa tome decisiones, es decir, que pueda ejecutar diferentes acciones según se cumpla o no una condición (como si una variable es mayor que otra, si es igual a cierto valor, etc.).

Esto hace que el programa sea dinámico y capaz de adaptarse a distintas situaciones, dependiendo de los datos que recibe o del estado actual de las variables.

¿Qué es un condicional?

Un condicional es una instrucción que permite tomar decisiones en un programa. Evalúa una expresión lógica, la cual puede ser:

• Verdadera
• Falsa

Dependiendo del resultado, el programa:

• • Ejecuta un bloque de instrucciones si la condición es verdadera.
• • Puede ejecutar un bloque diferente o no hacer nada si la condición es falsa.

Por ejemplo:

• edad > 18 //¿La persona es mayor de edad?

• nombre = "Juan" //¿El nombre ingresado es Juan?

• numero % 2 = 0 //¿El número es par?

Estas condiciones permiten al programa preguntar algo y actuar dependiendo de la respuesta.

¿Qué pasa sin condicionales?

Sin estructuras condicionales, un programa ejecutaría siempre lo mismo, sin importar los valores ingresados por el usuario ni el contexto. No podría:

• Verificar si un usuario tiene acceso.
• Saber si debe mostrar una advertencia.
• Determinar si debe repetir algo.

Tipos de estructuras condicionales:

En PSeInt, así como en muchos lenguajes de programación, existen varios tipos de estructuras condicionales, dependiendo de la complejidad de la decisión que se desea tomar.

Condicional Simple:

Se utiliza cuando queremos que el programa realice una acción solo si se cumple una condición.

Si la condición no se cumple, simplemente continúa con el resto del programa sin ejecutar nada adicional.

Sintaxis básica:

Si condición Entonces
  // Acciones si la condición es verdadera
FinSi

Ejemplo:

Escribir "Ingresa tu edad:";
Leer edad;
              
Si edad >= 18 Entonces
  Escribir "Eres mayor de edad";
FinSi

Condicional Doble:

Se utiliza cuando queremos que el programa elija entre dos caminos:

• Una acción si la condición es verdadera.
• Otra acción si la condición es falsa.

Sintaxis básica:

Si condición Entonces
  // Acciones si la condición es verdadera
SiNo
  // Acciones si la condición es falsa
FinSi

Ejemplo:

Escribir "Ingresa un número:";
Leer numero;
              
Si numero % 2 = 0 Entonces
  Escribir "El número es par";
SiNo
  Escribir "El número es impar";
FinSi

Condicional Anidado:

Cuando necesitas evaluar varias condiciones en orden, puedes colocar un condicional dentro de otro.

Esto permite tomar decisiones más complejas y detalladas.

Sintaxis básica:

Si condición1 Entonces
  // Acciones si condición1 es verdadera
          
Si condición2 Entonces
  // Acciones si condición2 también es verdadera
SiNo
  // Acciones si condición2 es falsa
FinSi

SiNo
  // Acciones si condición1 es falsa
FinSi

Ejemplo:

Escribir "Ingresa un número:";
Leer numero;
              
Si numero > 0 Entonces
  Escribir "El número es positivo";
SiNo
  Si numero < 0 Entonces
    Escribir "El número es negativo";
  SiNo
    Escribir "El número es cero";
  FinSi
FinSi

Condicional Múltiple:

Cuando tienes varias opciones posibles para una misma variable, lo mejor es usar la estructura Según, esta estructura permite evaluar diferentes casos posibles de una misma variable de forma más ordenada y legible que muchos Si...SiNo.

Sintaxis básica:

Segun variable Hacer
  Opcion1:
    // Acciones para el caso 1
  Opcion2:
    // Acciones para el caso 2
  ...
  De Otro Modo:
    // Acciones si ninguna opción anterior se cumple
FinSegun

Ejemplo:

Escribir "Elige una opción:";
Escribir "1. Sumar";
Escribir "2. Restar";
Escribir "3. Salir";
Leer opción;
              
Segun opcion Hacer
  1:
    Escribir "Elegiste Sumar";
  2:
    Escribir "Elegiste Restar";
  3:
    Escribir "Saliendo del programa...";
  De Otro Modo:
    Escribir "Opción no válida";
FinSegun