Condicionales

---

Las estructuras condicionales permiten que un programa tome decisiones, es decir, que ejecute diferentes acciones dependiendo del resultado de una condición lógica (como si una variable es mayor que otra, si es igual a cierto valor, etc.).

Estas decisiones son esenciales en la programación, ya que permiten que los programas sean dinámicos, es decir, que puedan reaccionar de distintas formas ante diferentes situaciones.

---

¿Qué es un condicional?

Un condicional es una construcción que permite evaluar una expresión que puede ser verdadera o falsa.

Dependiendo del resultado, el programa ejecutará ciertas instrucciones o tomará un camino diferente.

Por ejemplo:

• edad > 18
• nombre = "Juan"
• numero % 2 = 0

Si la expresión se cumple (es verdadera), el programa realiza una acción; si no se cumple (es falsa), puede hacer otra cosa o simplemente no hacer nada.

Sin condicionales, un programa ejecutaría siempre el mismo conjunto de instrucciones, sin importar la situación o los datos de entrada.

---

Tipos de estructuras condicionales:

En PSeInt y en la mayoría de lenguajes de programación, existen varias formas de trabajar con condicionales según el tipo de decisión que necesitemos tomar:

1. Condicional Simple:

Se utiliza cuando queremos que el programa realice una acción solo si se cumple una condición.

Si la condición no se cumple, el programa continúa normalmente sin realizar ninguna acción extra.

Sintaxis básica:

  Si condición Entonces
     // Acciones si la condición es verdadera
  FinSi

Ejemplo:

  Escribir "Ingresa tu edad:";
  Leer edad;
                        
  Si edad >= 18 Entonces
     Escribir "Eres mayor de edad";
  FinSi

2. Condicional Doble:

Se utiliza cuando necesitamos que el programa elija entre dos opciones:

• Una acción si la condición es verdadera.
• Otra acción si la condición es falsa.

Sintaxis básica:

  Si condición Entonces
     // Acciones si la condición es verdadera
  SiNo
     // Acciones si la condición es falsa
  FinSi

Ejemplo:

  Escribir "Ingresa un número:";
  Leer numero;
                        
  Si numero % 2 = 0 Entonces
     Escribir "El número es par";
  SiNo
     Escribir "El número es impar";
  FinSi

3. Condicional Anidado:

A veces es necesario evaluar varias condiciones de manera ordenada.

Un condicional anidado es cuando dentro de un Si...FinSi ponemos otro condicional.

Se utiliza cuando las decisiones son más complejas y dependen de varias verificaciones.

Ejemplo:

  Escribir "Ingresa un número:";
  Leer numero;
								
  Si numero > 0 Entonces
      Escribir "El número es positivo";
  SiNo
      Si numero < 0 Entonces
          Escribir "El número es negativo";
      SiNo
          Escribir "El número es cero";
      FinSi
  FinSi

4. Condicional Múltiple:

Cuando hay varias alternativas basadas en un único valor, es más claro usar una estructura llamada Segun, esta estructura permite evaluar diferentes casos posibles de una misma variable de forma más ordenada y legible.

Sintaxis básica:

  Segun variable Hacer
     Opcion1:
        // Acciones para el caso 1
     Opcion2:
        // Acciones para el caso 2
     ...
     De Otro Modo:
        // Acciones si ninguna opción anterior se cumple
  FinSegun

Ejemplo:

  Escribir "Elige una opción:";
  Escribir "1. Sumar";
  Escribir "2. Restar";
  Escribir "3. Salir";
  Leer opción;
                        
  Segun opcion Hacer
     1:
        Escribir "Elegiste Sumar";
     2:
        Escribir "Elegiste Restar";
     3:
        Escribir "Saliendo del programa...";
     De Otro Modo:
        Escribir "Opción no válida";
  FinSegun

---